WikiSort.ru - Программирование

Объекты

В RSL (в отличие от других языков программирования, к примеру, от C++) конструирование объектов происходит в два этапа:

• Создание объекта: выделение памяти с учётом [[Наследование (программирование)|иерархии наследования]], построение списков замен [[Виртуальный метод|виртуальных методов]], всем свойствам класса присваивается значение NULL. После этого, поскольку объект не содержит не-инициализированных данных, он готов к корректному разрушению.
• Инициализация объекта: вызов метода Init. Если инициализацию необходимо выполнить для класса-родителя, то его метод Init следует вызвать явно при инициализации класса-наследника.

Таким образом, в классах RSL деструкторы, определяемые пользователем, не применяются (объекты и их свойства удаляются автоматически).

Наследование

В RSL наследование позволяет описать новый класс на основе уже существующего (родительского, базового) класса. Таким образом, все методы и свойства класса-родителя также становятся методами и свойствами класса-наследника. Кроме этого, класс-наследник может добавлять свои свойства и методы или переопределять методы класса-родителя. Наследование позволяет строить иерархии классов. Множественное наследование в RSL запрещено.

При наследовании имя класса-родителя указывается в круглых скобках после ключевого слова Class. Для инициализации класса-родителя необходимо вызвать предопределенный метод, название которого образуется путём добавления к имени класса-родителя приставки Init.

Пример наследования классом Employee («Сотрудник») класса Person («Персона»), при добавлении к нему свойства Post («Должность»):

Class Person (Name, Surname)
   // Список свойств и методов класса Person
end;


Class (Person) Employee (Name, Surname, Post)
   InitPerson (Name, Surname);   // Инициализация класса Person в классе Employee 
   Macro Report()
      println("Post: ", Post);
   end;
end;

Инкапсуляция

В RSL инкапсуляция реализуется через указание уровня доступа к свойствам и методам класса, а также к переменным и процедурам макромодуля.

• В основной части макромодуля все переменные, процедуры и классы, объявленные без модификатора доступа, по умолчанию являются глобальными. Они становятся доступными не только внутри макромодуля, но и во всех остальных макромодулях, которые его импортируют. Также переменные можно сделать принудительно глобальными (об этом см. далее).
• Модификатор доступа private позволяет объявлять переменные, процедуры и классы как приватные, что накладывает запрет на доступ к ним извне. Этот модификатор является аналогом модификатора protected в C++.
• С помощью модификатора local можно объявлять переменные, объекты и процедуры как локальные. Локальные переменные доступны только локальным процедурам. Невозможно обратиться к локальной переменной внутри любой другой процедуры макромодуля.

local var str;     // Локальная переменная модуля, видима только
                   // в теле текущего модуля или в локальной процедуре
macro Proc1()         // Глобальная процедура модуля
   str = "Text1 ";    // Ошибка! str недоступна
end;


local macro Proc2()   // Локальная процедура модуля
   str = "Text2 ";    // Правильно!
end;


Proc2();
str = str + "Text3";  // Правильно!
println(str);

Если указать модификатор local перед свойством класса, то оно перестает быть свойством класса, как таковым, и становится локальной переменной конструктора. Таким образом, модификатор local применим только для процедур инициализации модуля и конструктора класса.

• Для получения доступа напрямую к переменным, которые находятся внутри процедур, нужно сделать их принудительно глобальными. Это осуществляется путём взятия их в фигурные скобки ({}):

macro Proc();
   var x = 2,     // К этой переменной не будет доступа вне процедуры
       {y} = 3;   // К этой переменной будет доступ вне процедуры
end;


Proc();           // Вызов процедуры


println(x);       // Ошибка: "неопределенный идентификатор x"
println({y});     // Результат: 3

При этом a и {a} — разные переменные. Если свойство класса взять в фигурные скобки, то оно перестанет быть свойством, как таковым, и стает глобальной переменной макромодуля. Обращение к нему будет осуществляться напрямую по имени, а не через ссылку на объект класса.

Уровни доступа к свойствам и методам класса:

Уровни доступа к переменным, процедурам и объектам макромодуля:

Полиморфизм

Все методы классов RSL являются виртуальными. Так, RSL реализует полиморфизм включения (или чистый полиморфизм) посредством наследования. При добавлении в классе-наследнике метода с именем, которое уже используется для одного из методов класса-родителя, метод наследника переопределит метод родителя. К методу родителя доступ будет только из метода наследника, который его переопределяет. Обращение к этому методу родителя осуществляется по его имени. Но в классе-наследнике вне переопределяющего метода не будет доступа к переопределенному методу родителя. Также станет невозможным обратиться к этому методу класса-родителя через ссылку на объект класса-наследника в основной части программы.

Class First()             // Класс-родитель
   Var x = 2, y = 3;


   Macro Sum()
      return x + y;
   end;
end;


Class (First) Second()    // Класс-наследник
   InitFirst();
   Var a = 100;


   Macro Sum()            // Начало переопределения родительского метода Sum()
      return Sum() + a;   //   Использование родительского метода Sum() в методе Sum() наследника 
   end;                   // Конец переопределения родительского метода Sum()


   Macro Sum2()
      return Sum() + a;   // Использование метода Sum() наследника
   end;
end;


obj = Second();           // Создание объекта класса Second()


println(obj.Sum());    // Результат: 105
println(obj.Sum2());   // Результат: 205

Если в этом примере из класса-родителя убрать метод Sum(), то в классе-наследнике произойдет рекурсивный вызов метода Sum().