WikiSort.ru - Программирование

Встроенные и определяемые пользователем типы

В языке Modelica имеются четыре встроенных типа: Real, Integer, Boolean, String. Определяемые пользователем типы обычно ассоциируются с физическими величинами, единицами, номинальными значениями и иными атрибутами:

type Voltage = Real(quantity="ElectricalPotential", unit="V");
type Current = Real(quantity="ElectricalCurrent", unit="A");
  ...

Соединители, описывающие физическое взаимодействие

Взаимодействие между компонентами определено физическими портами, называемыми соединители или коннекторы (connector). Так, например, электрический пин (штырь) определён как:

connector Pin "Electrical pin"
   Voltage      v "Potential at the pin";
   flow Current i "Current flowing into the component";
end Pin;

При рисовании линий соединения между портами смысл состоит в том, что соответствующие соединителю переменные без префикса «flow»^[20] идентичны (пример такой переменной здесь: «v»), а соответствующие соединителю переменные с префиксом «flow» (пример такой переменной здесь: «i») определены уравнением с нулевой суммой (сумма всех соответствующих переменных «flow» равна нулю). Мотивация состоит в том, чтобы автоматически выполнялись соответствующие уравнения баланса на сколь угодно малой точке соединения.

Базовые компоненты модели

Базовые компоненты модели определены моделью и содержат уравнения, описывающие взаимоотношения между переменными соединителя в декларативной форме, то есть без определения порядка вычислений. Вот например, модель конденсатора^[21]:

model Capacitor
  parameter Capacitance C;
  Voltage u "Voltage drop between pin_p and pin_n";
  Pin pin_p, pin_n;
equation
  0 = pin_p.i + pin_n.i;
  u = pin_p.v - pin_n.v;
  C * der(u) = pin_p.i;
end Capacitor;

Здесь C — ёмкость, pin_p и pin_n — обкладки конденсаторов, имеющие смысл пинов, u — разность потенциалов между обкладками pin_p и pin_n.

Первое уравнение выражает закон сохранения заряда для конденсатора (равенство зарядов на его обкладках), второе уравнение — разность потенциалов между обкладками, третье уравнение определяет переменный ток.

Цель состоит в том, чтобы связное множество компонентов модели приводило к системе дифференциальных, алгебраических и дискретных уравнений, у которых число уравнений совпадает с числом неизвестных. В языке Modelica это достигается за счёт т. н. сбалансированных моделей.

Полные правила для определения сбалансированных моделей довольно сложны, о них можно узнать из ^[1], раздел 4.7.

Однако для большинства случаев могут быть установлены простые правила, которые считают число уравнений и число неизвестных так, как это делают большинство средств, предназначенных для моделирования:

Модель сбалансирована, если число её уравнений равно числу её переменных.

Переменные и уравнения должны быть посчитаны по следующему правилу:

->Число уравнений модели                               = 
  Число уравнений, определённых в самой модели         + 
  число потоковых переменных из внешних соединителей
 
->Число переменных модели = Число переменных, определённых в самой модели,
  включая переменные в физических соединителях. 

Заметим, что стандартные соединители на входе (такие как RealInput или IntegerInput) не вносят вклада при счёте переменных, так как в них не определены новые переменные.

Смысл такого определения может быть пояснён на приведённом выше примере конденсатора. Каждый из его соединителей содержат потоковую переменную, то есть ток. При проверке оказывается, что эта переменная ни с чем не соединена. Это соответствует тому, что на каждом соединителе устанавливается уравнение pin.i=0. Вот почему должно быть добавлено уравнение для каждой потоковой переменной.

Пример может быть распространён на другие случаи, в которые вовлечены иные типы потоковых переменных, например, силы, моменты и т. д.

Представленная выше модель конденсатора сбалансирована, так как

number of equations =   3+2=5   (flow variables: pin_p.i, pin_n.i, u)
number of variables =       5   (u, pin_p.u, pin_p.i, pin_n.u, pi_n.i)

Верификация этой модели с помощью OpenModelica^[15] даёт:

Class Capacitor has 5 equation(s) and 5 variable(s).
3 of these are trivial equation(s).

Другой пример, содержащий как входящие, так и физические соединители представлен, следующей моделью из Modelica Standard Library:

model SignalVoltage 
  "Generic voltage source using the input signal as source voltage"
  Interfaces.PositivePin p;
  Interfaces.NegativePin n;
  Modelica.Blocks.Interfaces.RealInput v(unit="V") 
    "Voltage between pin p and n (= p.v - n.v) as input signal";
  SI.Current i "Current flowing from pin p to pin n";
equation 
  v = p.v - n.v;
  0 = p.i + n.i;
  i = p.i;
end SignalVoltage;

Компонент SignalVoltage сбалансирован, так как

number of equations =   3+2=5  (flow variables: pin_p.i, pin_n.i, u)
number of variables =       5  (i, pin_p.u, pin_p.i, pin_n.u, pi_n.i)

Проверка с помощью OpenModelica^[15] даёт:

Class Modelica.Electrical.Analog.Sources.SignalVoltage has 5 equation(s) and 5 variable(s).
4 of these are trivial equation(s).

Иерархические модели

Иерархическая модель составляется из базовых моделей с помощью базовых моделей-примеров за счёт соответствующих значений параметров модели и за счёт связей моделей с помощью соединителей. Типичный пример представлен следующей электрической цепью:

model Circuit
   Capacitor C1(C=1e-4) "A Capacitor instance from the model above";
   Capacitor C2(C=1e-5) "A Capacitor instance from the model above";
     ...
equation
   connect(C1.pin_p, C2.pin_n);
   ...
end Circuit;

С помощью языкового элемента annotation(…) определения могут быть добавлены к модели, что не будет сказываться на моделировании. Аннотации используются для графической выдачи, документации и информации о версиях. Базовое множество графических аннотаций стандартизовано таким образом, чтобы графические вид и выдача моделей были бы теми же самыми в различных реализациях языка Modelica.

Свободно распространяемая книга «Modelica by Example» содержит многочисленные примеры, похожие на данные, с детальным пояснением всех свойств языка Modelica версии 3.3.